Исполнитель Чертежник в 6 классе

 6 класс

Уроки по разделу: "Среда программирования PascalABC. Исполнитель Чертежник"

Скачать среду программирования PascalABC можно здесь

Урок 1. Знакомство со средой программирования. Написание программы линейной структуры.

СКИ (система команд исполнителя) "Чертежник":

pendown - опустить перо

penup - поднять перо

topoint (x,y) - перемещение в точку с координатами (х,у) 

onvector (a,b) - перемещение на вектор относительно текущего положение х+a, x+b

Шаблон программы:
uses DrawMan; {использовать исполнитель Чертежник}
begin
task ( 'a1' );
...
end.

Задание будет проверено автоматически.
Чертежник в конце программы должен вернуться в точку начала координат.

Выполняем задания а1, а2, а3 и т.д. (дома по желанию).

Урок 2. Цикл с известным числом повторений.

for i:=1 to конечный параметр do
begin
...
end;

i - параметр цикла изменяется от начального значения (=1) до конечного значения (по заданию) с шагом =1.
i - переменная (объект в программировании, который в программе меняет свое значение).
Переменные в начале программы записываются в блоке var (variable).
Записывается имя переменной и ее тип. Тип integer означает целочисленный тип.
Образец:  var i: integer;

Шаблон программы:
uses DrawMan;
var i: integer;     {блок описания переменных}
begin                {начало программы}
task ( 'c1' );     {задание}
 topoint (1,3);
 for i:=1 to 15 do
       begin
         pendown;
         onvector (0,-1);
         onvector (1,1);
      end;
 penup;
 topoint (0,0);     {возврат в точку начала координат}
end.  {конец программы}

Задание будет проверено автоматически.
Чертежник в конце программы должен вернуться в точку начала координат.

Выполняем задания c2 - c9  (что не успели на уроке - дома по желанию).


Урок 3. Параметр цикла управляет координатой смещения команды onvector.

На уроке рассматриваем задание с10.

uses DrawMan;
var i:integer;
begin
task ( 'c10' );
topoint (2,1);
 for i:=1 to 10 do
 begin
 pendown;
 onvector ( 0 , i ); {параметр цикла задает параметр смещения  }
 onvector ( 1, -i );
 end;
 penup;
 topoint (0,0);
end.

Выполняем задания c10 - c15  (что не успели на уроке - дома по желанию).


Урок 4. Параметр цикла управляет координатой смещения команды onvector.

На уроке рассматриваем задание с17

uses DrawMan; {использовать исполнитель Чертежник}
var i:integer;
begin
task ( 'c17' );
topoint (1,2);
 for i:=1 to 14 do
 begin
 pendown;
 onvector (i*2-1,0); {параметр цикла задает параметр смещения  }
 penup;
 onvector (-(i*2-1),1);
 end;
 penup;
 topoint (0,0);
end.

Выполняем задания c17 - c25  (что не успели на уроке - дома по желанию).


Урок 5. Вложенные циклы

На уроке рассматриваем задание сс1.

uses DrawMan; {использовать исполнитель Чертежник}
var i,j:integer;
begin
task ( 'cc1' );
topoint (1,1);
for j:=1 to 4 do     {внешний цикл}
     for i:=1 to 5 do   {внутренний цикл}
            begin
            pendown;
           onvector (1,j);
           onvector (0,-j);
           end;
 penup;
 topoint (0,0);
end.

Выполняем задания cс1 - сc14  (что не успели на уроке - дома по желанию).

Урок 6. Подпрограммы (процедуры)

Процедурой (подпрограммой) называется участок программы, выполняемый многократно.
Записывается код процедуры в начале программы, а запускается в основной программе по имени несколько раз. После имени процедуры. в скобках указывается формальный параметр. Значение которого задается при вызове процедуры в основной программе.

На уроке рассматриваем задание pp1.

uses drawman;
procedure square (a:integer); {запись процедуры, а - формальный параметр}
begin
pendown;
onvector (a,0);
onvector (0,a);
onvector (-a,0);
onvector (0,-a);
penup;
end;

begin
task ('pp1'); 
topoint (2,1);
square (1);         {вызов процедуры с указанием фактического параметра = 1}
topoint (3,4);
square (3);        {вызов процедуры с указанием фактического параметра = 3}
topoint (8,8);
square (2);        {вызов процедуры с указанием фактического параметра = 2}
topoint (10,2);
square (4);        {вызов процедуры с указанием фактического параметра = 4}
topoint (0,0);
end.

Выполняем задание рр2.

uses drawman;
var i:integer;
procedure square (a : integer);
begin
pendown;
onvector (a,0);
onvector (0,a);
onvector (-a,0);
onvector (0,-a);
penup;
end;

begin
task ('pp2');
topoint (2,1);

for i:=1 to 8 do   {для чего нужен цикл??}
begin
square (i);
end;
topoint (19,9);

....                  {написать 2 часть программы}

topoint (0,0);
end.

Самостоятельно выполняем задания рр3 и рр4.